home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FLOAT / FPCMP.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  3KB  |  88 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAIMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Last Update 3 Nov 87   Version 2.1
  7. ;
  8. fpcmp   ident   2,1
  9. ;
  10. ; MOTOROLA DSP56000/1 FPLIB - VERSION 2
  11. ;
  12. ; FPCMP - FLOATING POINT COMPARISON (SETS CONDITION CODES) SUBROUTINE
  13. ;
  14. ;
  15. ; Entry points: fcmp_xa A - X   SET CONDITION CODES
  16. ;               fcmp_xy Y - X   SET CONDITION CODES
  17. ;
  18. ;       m = 24 bit mantissa (two's complement, normalized fraction)
  19. ;
  20. ;       e = 14 bit exponent (unsigned integer, biased by +8191)
  21. ;
  22. ; Input variables:
  23. ;
  24. ;   X   x1 = mx  (normalized)
  25. ;       x0 = ex
  26. ;
  27. ;   Y   y1 = my  (normalized)
  28. ;       y0 = ey
  29. ;
  30. ;   A   a2 = sign extension of ma
  31. ;       a1 = ma  (normalized)
  32. ;       a0 = zero
  33. ;
  34. ;       b2 = sign extension of ea (always zero)
  35. ;       b1 = ea
  36. ;       b0 = zero
  37. ;
  38. ; Output variables:
  39. ;
  40. ;       The following Jcc branch conditions can be used after calling
  41. ;       fcmp_xa or fcmp_xy.  The other branch conditions should not be used.
  42. ;
  43. ;       "cc" Mnemonic                   Condition
  44. ;       -------------                   ---------
  45. ;       EQ - equal                      Z = 1
  46. ;       GE - greater than or equal      N eor V = 0
  47. ;       GT - greater than               Z + (N eor V) = 0
  48. ;       LE - less than or equal         Z + (N eor V) = 1
  49. ;       LT - less than                  N eor V = 1
  50. ;       NE - not equal                  Z = 0
  51. ;
  52. ; Error conditions:     none
  53. ;
  54. ; Assumes n0, m0, shift constant table and scaling modes
  55. ; initialized by previous call to the subroutine "fpinit".
  56. ;
  57. ; Alters Data ALU Registers
  58. ;       a2      a1      a0      a
  59. ;       b2      b1      b0      b
  60. ;               x0              y0
  61. ;
  62. ; Alters Address Registers
  63. ;
  64. ;
  65. ; Alters Program Control Registers
  66. ;       pc      sr
  67. ;
  68. ; Uses 0 locations on System Stack
  69. ;
  70. ;
  71. fcmp_xy tfr     y0,b    y1,a            ;get ey, my
  72. fcmp_xa eor     x1,a    a,y0            ;compare signs, save ma
  73.         jmi     _mant                   ;jump if different signs
  74. ;
  75. ; Same signs
  76. ;
  77. _sign   eor     x1,a                    ;check sign of ma
  78.         jpl     _sign1                  ;jump if ma and mx positive
  79.         tfr     x0,b    b,x0            ;if minus, exchange ea and ex
  80. _sign1  cmp     x0,b                    ;compare exponents
  81.         jne     done                    ;jump if different exponents
  82. ;
  83. ; Same signs, same exponents or different signs
  84. ;
  85. _mant   tfr     y0,a                    ;restore ma
  86.         cmp     x1,a                    ;compare mantissa
  87.         rts
  88.